超簡單！教你在家用版Windows上啟用沙箱功能！

 

大家好，在本期影片中，將向大家展示如何快速啟用家用版Windows的沙箱功能，這個功能可以臨時創建一個虛擬作業系統，讓我們可以安全地測試下載的軟體、檔案或特定網站。通過沙箱，我們可以極大地降低中毒的風險。一般來說，沙箱和Hyper-V功能只在專業版Windows中可用，但是我們可以使用特定的指令碼在家用版Windows上啟用它們。在影片中，我將分三個部分介紹：1. 主機板虛擬化功能的開啟方法，2. 家用版Hyper-V功能的啟用，3. 家用版Windows沙箱功能的啟用。這些步驟簡單易懂，讓我們一起來學習如何保護電腦安全吧！

Hyper-V 家用版啟用指令碼

pushd "%~dp0"

dir /b %SystemRoot%\servicing\Packages\*Hyper-V*.mum >hyper-v.txt

for /f %%i in ('findstr /i . hyper-v.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"

del hyper-v.txt

Dism /online /enable-feature /featurename:Microsoft-Hyper-V-All /LimitAccess /ALL

 

Windows沙箱 家用版啟用指令碼

@echo off
echo Checking for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
echo Permission check result: %errorlevel%
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
echo Running created temporary "%temp%\getadmin.vbs"
timeout /T 2
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
echo Batch was successfully started with admin privileges
echo .
cls
Title Sandbox Installer
pushd "%~dp0"

dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt
for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
del sandbox.txt
Dism /online /enable-feature /featurename:Containers-DisposableClientVM /LimitAccess /ALL

pause